Exit-Room Telefon mit Arduino Uno und DFPlayer Mini

/* ExitRoomTelefon V1.0 (c) Oliver Mezger 16.05.2020 */
 
#include <SoftwareSerial.h>
#include <DFPlayerMini_Fast.h>
 
#define Telefonpin 12 // zum Telefon
#define Testoutput 13 // zur Kontrolle
#define W_Pegel_Max 10
#define W_Pegel_Tlow 4 // Threshold low Schaltschwelle
#define W_Pegel_Thigh 6 // Threshold high
 
unsigned char wPegel = W_Pegel_Max; // zeitlicher Pegel
bool wSignal = 1; // Zustand nach Threshold
SoftwareSerial mySerial(10, 11); // RX, TX
DFPlayerMini_Fast myMP3;
unsigned long myMillis;
 
void setup() {
  Serial.begin(115200);
  mySerial.begin(9600);
 
  myMP3.begin(mySerial);
 
  Serial.println("Setting volume to 20");
  myMP3.volume(20); // 0..30
  delay(20);
  pinMode(Telefonpin,INPUT);
  pinMode(Testoutput,OUTPUT);
  myMillis=millis(); 
}
typedef enum {ruhe,impuls,play} wZustandtyp;
wZustandtyp wZustand = ruhe;
 
void loop() {
  static bool wImpuls = 0; // steigende Flanke
  static unsigned char wImpulse = 0; // Impulszaehler
  static unsigned long wMillis;
  // Einlesen des Telefonpins und entstören des Signals
  if(myMillis+2<=millis()){ // wenn 2ms vergangen sind
    myMillis=millis();
    if(digitalRead(Telefonpin)){ // wenn 1
      if(wPegel<W_Pegel_Max) wPegel++;
    }
    else if (wPegel>0) wPegel--;
    if(wSignal){ // Schmitt-Trigger
      if(wPegel<= W_Pegel_Tlow){ // unter Threshold unterschritten
        wSignal=0;
        digitalWrite(Testoutput,LOW); // Testausgabe
      }
    }
    else if (wPegel >= W_Pegel_Thigh){ // oberer Threshold ueberschritten
      wSignal=1;
      digitalWrite(Testoutput,HIGH);  // Testausgabe
      wImpuls=1; // ein Waehlimpuls
    }
  }
  // Zustands-Automat
  switch(wZustand){ // Wahlzustaende
    case ruhe: // warten auf Impuls
      if(wImpuls){
        wZustand=impuls;
        wImpulse = 0;
        wMillis=1100+millis(); // nach 1,1 sec ist Nummer durch
      }
      break;
    case impuls: // Impulse zaehlen
      if(wImpuls){
        wImpuls=0;
        wImpulse++;
      }
      if(millis()>wMillis) wZustand=play; // Zeit ist um
      break;
    case play: // Stueck spielen
      Serial.println(wImpulse); // Testausgabe
      myMP3.play(wImpulse); // spiele Stueck 1..10
      wZustand = ruhe;
  }
}