Fragen, Übungen und Klassenarbeiten

Begriffe und Grundlagen

Worin unterscheidet sich ein Microcontroller von einer CPU? Der Controller ist ne CPU + X: I/O Peripherie (Ports, A/D Wandler, D/A Wandler, Serielle Schnittstellen usw..), RAM, ROM, Timer. Man denke an die Anwendungen: Auto, Handy, Waschmaschiene, Tintenpisser, Modem, Fahrrad (Computergesteuerte Gangschaltung).

Erklären Sie den Begriff Befehlszyklus anhand eines Beispiels.

Welche Aufgabe hat der Assembler? de.wikipedia.org/wiki/Assemblersprache

Worin besteht der Unterschied zwischen CISC und RISC? de.wikipedia.org/wiki/Reduced_Instruction_Set_Computing

Was sind MIPS? Milionen Instruktionen pro Sekunde

Was bewirkt ein Reset? Register und PC werden auf Null gesetzt: Folge Programm beginnt wieder bei Adresse 0

Erklären Sie die Abkürzungen MSB und LSB? Most Significant Bit -> Das Bit ganz links hat die grösste Wertigkeit...

Der Flash-Speicher des ATtiny2313 ist 2KByte gross, als 16 Bit organisiert.

Wofür wird der Flash-Speicher verwendet? Er ist der Programm- und Konstantdatenspeicher.

Wie oft kann der Flash-Speicher wiederbeschrieben werden? Mindestens 10000 mal.

Warum ist der Speicher 16 Bit organisiert? Weil die Befehle 16 bzw. 32 Bit lang sind.

Wie viele Adressen hat der 2kiB Flash-Speicher? Da er 16 Bit organisiert ist: 2048 Byte / 2 Byte = 1024 Adressen.

In Assember übersetzen

Dem Assembler seien schon die 1Byte Register-Variablen a,b,c bekannt.

Erstellen Sie Assembler-Programme für folgende Rechnungen und ermitteln Sie die Anzahl der Takte zur Bearbeitung:

Lösung anzeigen..

.include "tn2313def.inc"
 
.def a = R16 ;R16 als Variable a
.def b = R17 ;R17 als Variable b
.def c = R18 ;R18 als Variable c
 
; Aufgabe 3.1 a=b+c
  mov a,b
  add a,c
; Aufgabe 3.2 b=b-c
  sub b,c
; Aufgabe 3.3 a=a+1
  inc a
; Aufgabe 3.4 b=b-3
  subi b,3
; Aufgabe 3.5 if(b==0)a=c
  cpi b,0
  brne weiter
  mov a,c
weiter:  

Rechnen in Assembler

Geben Sie den Inhalt von SREG-Flags N,Z,C und dem Register R16 nach der Ausführung des Befehls an. Gehen Sie davon aus, dass vor dem ersten Befehl N,Z,C gelöscht (0) sind.

Programm analysieren

.include "tn2313def.inc"

.def a = R16 ;R16 als Variable a
.def b = R17 ;R17 als Variable b
.def c = R18 ;R18 als Variable c

  ;Zuweisen von Werten a,b

adam:
  cp a,b
  brmi eva
  mov c,a
  sub c,b
  rjmp gogo
eva:
  mov c,b
  sub c,a
gogo:
    ...

if(a>=b)
  c=a-b;
else
  c=b-a;

Programm erstellen

Erstellen Sie ein Programm (Assembler mit PAP) das berechnet:

Wenn a gerade dann b = 1 sonst b = 0.

; Trick: wenn a gerade dann ist Bit0 = 0
; einfache Loesung
  mov b,a     ;a soll ja nicht veraendert werden
  andi b,1    ;maskiere Bit 0
  breq gerade ;wenn 0 dann gerade
  ldi b,0     ;ist ungerade
  rjmp ende
gerade:
  ldi b,1
ende:
 
; bessere Lösung
  sbrc a,0 ;ueberspringe naechsten Befehl wenn Bit0=0
  ldi b,0  ;sonst ist Bit0=1 also ungerade
  sbrs a,0 ;ueberspringe naechsten Befehl wenn Bit0=1
  ldi b,1  ;sonst ist Bit0=0 also gerade
 
; pfiffige Loesung
  mov b,a     ;a soll ja nicht veraendert werden
  com b       ;bilde Einerkomplement: invertiere alle Bits
  andi b,1    ;maskiere Bit0

Programm analysieren

Analysieren Sie folgendes Assembler-Programm.

.include "tn2313def.inc"

.def tmp = R16
.def merker = R17

init:
  out DDRD,tmp
  out PORTD,tmp
  ldi tmp,0xFF
  out DDRB,tmp
  out PORTB,tmp
atest:
  in tmp,PIND
  andi tmp,0x40
  brne btest
  in merker,PIND
  andi merker,0x0F
btest:
  in tmp,PIND
  andi tmp,0x20
  brne atest
  in tmp,PIND
  andi tmp,0x0F
  cp tmp,merker
  brne nein
  out PORTB,tmp
  rjmp atest
nein:
  ldi tmp,0xFF
  out PORTB,tmp
  rjmp atest 

.include "tn2313def.inc"
 
.def tmp = R16
.def merker = R17
 
init:
  out DDRD,tmp
  out PORTD,tmp
  ldi tmp,0xFF
  out DDRB,tmp
  out PORTB,tmp
atest:
  sbic PIND,6 ;wenn Taste A gedrueckt ueberspringe Befehl
  rjmp btest
  in merker,PIND
  andi merker,0x0F
btest:
  sbic PIND,5 ;wenn Taste B gedrueckt ueberspringe Befehl
  rjmp atest
  in tmp,PIND
  andi tmp,0x0F
  cp tmp,merker
  brne nein
  out PORTB,tmp
  rjmp atest
nein:
  ldi tmp,0xFF
  out PORTB,tmp
  rjmp atest 

Programm Analyse 10 Punkte

Gegeben ist folgender Assember-Code:

.include "tn2313def.inc"
.def a = R16 ;R16 als Variable a
start:
   ldi a,0
loop:
  dec a
  brne loop 
stop:

Erstellen Sie einen PAP. 3 PunkteLösung

Ermitteln Sie die Anzahl der Taktzyklen (nachvollziebare Rechnung) zwischen start: und stop:. 1+ 255*3 + 2 = 3*256 = 768 5 Punkte

Wie viel Zeit vergeht dabei, wenn der µController mit 10 MHz betrieben wird?  2 Punkte76,8 us

Verzweigung 10 Punkte

Der C-Code char a,b; ... b=0; if(a<0) b=1; soll in Assembler übersetzt werden.

Erstellen Sie ein Assembler Programm. 5 Punk

  ldi b,0
  cpi a,0
  brsh weiter
  ldi b,1
weiter:        

Erstellen Sie einen PAP zu Ihrem Programm. 2 Punkte

Mit welchen Testwert-Ergebnis-Kombinationen (Tabelle: Eingabe -> Ausgabe) müssen Sie Ihr Programm testen, damit Sie die Korrektheit beweisen können, begründen Sie! 3 PunkteMit a ∈ {0,1,-1} Fehler treten oft um die Grenze, hier 0 auf.

Schleife

Der C-Code unsigned char a,b; ... for(a=2; a<6; a=a+2) b=a; soll in Assembler übersetzt werden.

Erstellen Sie ein Assembler Programm.

  ldi a,2
forloop:
  cpi a,6
  brsh forend
  mov b,a
  subi a,-2
  rjmp forloop
forend:

Erstellen Sie einen PAP zu Ihrem Programm.

Welchen Wert haben a und b nach dem Ende der Schleife? a=6; b=4

Initialisierung und einfache Logik-Verknüpfung 30 Punkte

Der µC ist wie in nebenstehender Tabelle beschaltet.

Die LED leuchten bei logisch 0, die Taster S4..1 führen bei Betätigung logisch 0 und benötigen einen aktivierten Pull-Up Widerstand im µC. Die LED sollen nicht leuchten. Offensichtlich wird in dieser Aufgabe negative Logik verwendet!

Erstellen Sie die notwendige Programm-Sequenz um die Initalisierung der Ports vorzunehmen. 5 Punkte

.def tmp = R16
init:
  ldi tmp, 0x0f
  out PORTB, tmp ;LED dunkel
  out DDRB, tmp ;PB3..PB0 als Ausgang
  out PORTD, tmp ;Pull-Up an

Ein Assembler-Programm soll entwickelt werden, das die folgenden Gleichungen realisiert:

LED1 = S1 oder S2 oder S3; LED2 = S4 xor S3 (PB0 = PD2 und PD1 und PD0; PB1 = PD3 xnor PD2)

Vor der Entwicklung soll bereits eine Tabelle zum späteren Testen der Software erstellt werden. Verwenden Sie diese Vorgabe: 5 Punkte

Erstellen Sie das sinnvoll kommentierte Assembler-Programm für die Gleichungen. 10 Punkte

loop:   
  ;PB0 = PD2&PD1&PD0	gdw =7
  in tmp, PIND
  andi tmp, 0x07 ;maskieren
  cpi  tmp, 0x07 ;
  breq pb4_set
  cbi PORTB,0 ;loesche Bit
  rjmp teil2
pb4_set:
  sbi PORTB,0
teil2: ;PB1 = PD3 xnor PD2
  in tmp, PIND
  andi tmp,0b1100 ;maskieren
  breq pb5_set    ;beide 0 setze Bit
  cpi tmp, 0b1100 ;beide 1 setze Bit
  breq pb5_set
  cbi PORTB,1     ;sonst loesche Bit
  rjmp loop       ;neuer Durchlauf
pb5_set:
  sbi PORTB,1
  rjmp loop 
  ...

Zeichnen Sie zu Ihrem Assembler-Code den dazu gehörenden Programm Ablauf Plan (PAP). 5 Punkte

Ermitteln Sie aus Ihrem Assembler-Code die maximale Reaktionszeit bei einer Taktfrequenz von 4MHz, d.h. wie lange dauert es maximal zwischen einer Tasteränderung und einer Ausgabe auf die LED. Der Gedankengang muss erkennbar sein. 5 Punkte

Indirektes Adressieren

Bestimmen Sie aus dem Assembler-Code die Adressen und den Inhalt der Flash-Speicherzellen.

.org $80
moni:
  .db 20,32,0b110,0x53
bernd:
  .db "Holla",0

ASCII-Tabelle (7Bit)

Stroboskop 30 Punkte

Ein Stroboskop soll 10 Lichtblitze pro Sekunde abgeben. Dazu erzeugt ein ATtiny2313 an PB0 ein Signal das im Prinzip so aussieht:

0	1	2	3	4	5	6	7	8	9	10	11

• Der Abstand der steigenden Flanken beträgt 100 ms.
• Der Impulsabstand wird mit dem 8Bit Timer 0 per Overflow-Interrupt erzeugt.
• Die Impulsdauer beträgt 1 ms und wird per Warteschleife erzeugt.
• Der µC arbeitet mit 500 kHz Systemtakt! BEACHTEN bei allen Aufgabenteilen!

Ermitteln Sie die optimale Einstellung des Timer-Vorteilers und den Vorspannwert des Timers für einen Interruptabstand von 100 ms. 5 Punkte

Taktzahl: 500 kHz * 100 ms = 50.000
Vorteiler: 50.000 / 256 = 195,3 gewählt 256
Vorsteller: 256 -(50.000/256) = 60,7 gewählt 61
Genauigkeit: (256-61)*256/500 kHz = 99,84 ms

Entwickeln Sie kommentierten Assemblercode für die Initialisierungen und das Hauptprogramm. 10 Punkte

  rjmp init  ;nach Reset init
  .org OVF0addr
  rjmp isrOVF0  ;Sprung zur ISR
  .org INT_VECTORS_SIZE
init:
  ldi R16, low(RAMEND)
  out SPL, R16 ;Stackpointer initialisieren
  ldi R16,1
  out DDRB, R16   ; PB0 als Ausgang
  ldi R16, 0b100  ;
  out TCCR0B, R16 ;Vorteiler 256
  ldi R16, 1<<TOIE0
  out TIMSK, R16  ;Overflow-Interrupt freischalten
  ldi R16,61      ;Vorspannen 256-195
  out TCNT0,R16   ;
  sei ;globale Interruptfreigabe
loop:
  rjmp loop

Entwickeln Sie kommentierten Assemblercode für ein Unterprogramm warte_1ms. 5 Punkte

warte_1ms:
  ldi R17,125 ;initialisieren
wloop:
  dec R17
  nop
  brne wloop
  ret		

Entwickeln Sie kommentierten Assemblercode für die Interruptbehandlungsroutine isrOVF0. 10 Punkte

isrOVF0:
  in R17,SREG
  push R17    ;SREG retten
  ldi R17,61  ;Vorspannen Timer
  out TCNT0,R17
  sbi PORTB,0 ;PB0 an
  rcall warte_1ms
  cbi PORTB,0 ;PB0 aus
  pop R17     ;SREG wieder herstellen
  out SREG, R17
  reti

Gebrauchte Klassenarbeiten

Das Reaktionsspiel

reaktionsspiel-ka.pdf

reaktionsspiel-lsg.pdf

ReaktionS1.c

Der Zeitwächter

zeitwaechter-ka.pdf

zeitwaechter-lsg.lsg